Parametric Portable Monitor Stand

Recently, I purchased an external LCD monitor to use while working on my computer when I’m away from home or the office. I’m so used to working with two monitors that having to rely on just the laptop screen becomes annoying.

The monitor, although fairly inexpensive, is well made and comes with a magnetic cover that also acts as a stand. The only limitation is that it supports just one viewing angle and can hold the monitor only in a horizontal position.

So I designed this simple stand, making it fully customizable in every aspect so it can be adapted to anyone’s needs. The stand allows the monitor to be supported at two different angles.

You can download the design from the link at the end of the article, or you can customize it online directly on MakerWorld.

This is a compact and lightweight stand designed to hold a portable LCD monitor securely in both vertical and horizontal orientations. Ideal for minimal desk setups or on-the-go use, it combines functionality with maximum customization.

The model is fully parametric and customizable in all dimensions: you can easily define the width, height, and depth to perfectly suit your monitor and space requirements.

At both ends, the stand features dedicated slots to hold the monitor in place.

Each slot’s angle, width, depth and distance from the stand’s edge can be independently adjusted, allowing for optimal fit and viewing comfort.

Make sure to accurately measure the thickness of your monitor and set the width parameter accordingly for each end of the stand.

For best results, try a 50-degree angle for horizontal placement and a 70-degree angle for vertical orientation. Feel free to fine-tune the angles to match your personal preferences.

Additionally, the rounding of each corner can be fine-tuned by setting a custom corner fillet percentage, giving you control over both aesthetics and ergonomics.

Perfect for makers, tinkerers, or anyone looking for a tailored display solution.

The model

Since the model was particularly simple, I created it using OpenSCAD to make the design fully parametric.
I had never worked with this tool before, but in the end, it turned out to be relatively easy to use—thanks in part to external libraries like BOSL2.

The parameters

All the dimensions of the model can be customized directly using OpenSCAD’s “Customizer” feature.

Below is the list of all adjustable parameters.

The source code

Copy to Clipboard

// Author: @StefanoBertini
// License: CC-Attribution-NonCommercial-ShareAlike 4.0

/* 
 *
 * Licensing: This work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License.
 * Further information is available here - https://creativecommons.org/licenses/by-nc-sa/4.0/
 *
 * v1 2025/05/12 - First release
 * 
 */

/* [Dimensions] */

// Support base width
width = 80;

// Support height
height = 22;

// Support depth
depth = 12.0;

/* [Left side] */

// Support inclination
left_angle = 70; //[45:90]

// Distance between the edge and the recess
left_border = 6.00;

// Depth of the recess
left_depth = 14.00;

// Width of the recess 
left_width = 9.60;

/* [Right side] */

// Support inclination
right_angle = 50;//[45:90]

// Distance between the edge and the recess
right_border = 6.00;

// Depth of the recess
right_depth = 14.00;

// Width of the recess 
right_width = 9.60;

/* [Corner rounding] */

// Bottom corners rounding radius
lower_corner_radius = 3.0;//[0:5]

// Upper corners rounding radius
upper_corner_radius = 2.0;//[0:3]

// Inner corners rounding radius
inner_corner_radius = 1.0;//[0:2]

include <BOSL2/std.scad>;
include <BOSL2/rounding.scad>;

/* [Hidden] */
a = [0,0];

b = [height / sin(left_angle) * cos(left_angle), 
    height];
    
c = [b[0] + left_border, 
    height];
    
d = [height / sin(left_angle) * cos(left_angle) - left_depth * cos(left_angle) + left_border, 
    height - left_depth * sin (left_angle)];
    
e = [d[0] + left_width * sin(left_angle), 
    d[1] - left_width * cos(left_angle)];

f = [e[0] + (height-e[1]) / sin(left_angle) * cos(left_angle), height];
  
k = [width - height * (cos(right_angle)/ sin(right_angle)), 
    height];
    
j = [k[0] - right_border, 
    height];   
    
i = [j[0] + right_depth * cos(-right_angle), 
    j[1] + right_depth * sin(-right_angle)]; 
    
h = [i[0] - right_width * sin(right_angle), 
    i[1] - right_width * cos(right_angle)];

g = [h[0] - (height - h[1]) / sin(right_angle) * cos(right_angle),
    height];
    
l = [width, 0];

points = [a,b,c,d,e,f,g,h,i,j,k,l];

radius = [lower_corner_radius,upper_corner_radius,inner_corner_radius,0,0,inner_corner_radius,
          inner_corner_radius,0,0,inner_corner_radius,upper_corner_radius,lower_corner_radius];

linear_extrude(height = depth, scale = 1)
    polygon(round_corners( points, radius=radius, method="circle" ));

Downloads